verbatimtex
\documentclass{article}
\usepackage{mztimesm}
\begin{document}
etex
beginfig(1)

pair c,b,a,s,cc,bb,aa,ss,cb,ba,as,sc;
numeric u; u=5mm;

c=(2u,5u);
b=(5u,-u);
a=(10u,7u);
s=b+(u,4u);

c-cc=2u*(0,1);
b-bb=-2.2u*(0,1);
a-aa=2.5u*(0,1);
s-ss=-0.7u*(0,1);

cb=whatever[c,b]=whatever[cc,bb];
as=whatever[a,s]=whatever[aa,ss];
ba=whatever[b,a]=whatever[bb,aa];
sc=whatever[s,c]=whatever[ss,cc];

fill (1u,-2u)--(10u,-2u)--(7u,5u)--(3u,5u)--cycle withcolor 0.8white;

pickup pencircle scaled 1.2pt;
draw c--sc;
draw c--cb;
draw a--ba;
draw a--as;
draw cb--b dashed evenly;
draw b--ba dashed evenly;
draw s--sc dashed evenly;
draw s--as dashed evenly;

pickup pencircle scaled 4pt;
draw a;
draw s;
draw b;
draw c;
draw cb;
draw ba;
draw sc;
draw as;

label.lft(btex $C$ etex, c);
label.bot(btex $B$ etex, b);
label.rt(btex $A$ etex, a);
label.lft(btex $S$ etex, s-(0.1u,0.2u));
label.top(btex $T$ etex, sc);
label.bot(btex $P$ etex, ba+(0.1u,0));
label.lft(btex $M$ etex, cb);
label.top(btex $K$ etex, as);

endfig;

bye